@echo off
:mainmenu
cls
rem  **** INPUT SELECTION

echo.
echo ----------- MECHWARRIOR 2 DEMO SETUP MAIN MENU -----------
echo.
echo NOTE: If this is the first time you have run the demo, please
echo       make sure to run options 1 and 2 on the menu below before
echo       attempting to start the demo.
echo.
echo What would you like to do?:
echo.
echo         1 = Change Input Device (Joystick/Mouse/Keyboard)
echo         2 = Select Sound Card
echo         3 = View MechWarrior 2 Demo Technical Information
echo         4 = Print MechWarrior 2 Demo Technical Information
echo         5 = Start Game or Exit
echo.
echo NOTE: A printer must be connected if you select option 4.
echo.
echo Press a number (1 through 5) to select the option you want:
echo.
choice /c:12345
echo.
if errorlevel 5 goto end
if errorlevel 4 goto printit
if errorlevel 3 goto readit
if errorlevel 2 goto sound
if errorlevel 1 goto controls

:printit
type mw2info.txt >prn
goto mainmenu

:readit
edit mw2info.txt
goto mainmenu

:controls
cls
echo.
echo ----------- MECHWARRIOR 2 DEMO INPUT DEVICE MENU -----------
echo.
echo Please choose an input device:
echo.
echo         1 = CH Flightstick
echo         2 = Thrustmaster Flight Control System
echo         3 = Microsoft Sidewinder
echo         4 = Standard joystick
echo         5 = Microsoft compatible mouse
echo         6 = Keyboard
echo         7 = No Change
echo.
echo Press a number (1 through 7) to select the option you want:
echo (Please note that for this demo, you cannot use a joystick
echo for modem play.  Only mouse and keyboard are supported.
echo Joystick play will be supported in the full modem version.)
echo.
choice /c:1234567
echo.
if errorlevel 7 goto mainmenu
if errorlevel 6 goto keyboard
if errorlevel 5 goto mouse
if errorlevel 4 goto standard
if errorlevel 3 goto micro
if errorlevel 2 goto thrust
if errorlevel 1 goto ch
goto mainmenu

:keyboard
del \mw2demo\input.map
echo Copying keyboard map
copy keyboard.map input.map
goto mainmenu

:mouse
del \mw2demo\input.map
echo Copying mouse map
copy mouse.map input.map
goto mainmenu

:standard
del \mw2demo\input.map
echo Copying standard joystick map
copy joystick.map input.map
goto mainmenu

:micro
del \mw2demo\input.map
echo Copying Microsoft joystick map
copy msjstick.map input.map
goto mainmenu

:thrust
del \mw2demo\input.map
echo Copying Thrustmaster Flight Control System map
copy tmaster.map input.map
goto mainmenu

:ch
del \mw2demo\input.map
echo Copying CH Flightstick map
copy fltstck.map input.map
goto mainmenu

:sound
cls
echo.
echo.
echo The SETSOUND utility will now run.  Through this utility, you will be
echo able to select your music and digital audio sound cards.
echo.
echo After SETSOUND has successfully run, type "mw2demo"
echo to run the MechWarrior 2 demo.
echo.
pause
CD \MW2DEMO\SND
setsound
cd ..
goto mainmenu

:end
cls
echo.
echo ----------- MECHWARRIOR 2 DEMO GAME MENU -----------
echo.
echo What would you like to do?:
echo.
echo         1 = Run the MechWarrior 2 DEMO (Standard VGA)
echo         2 = Run the MechWarrior 2 DEMO (SVGA Mode)
echo         3 = Return To Previous Menu
echo         4 = Exit To DOS
echo.
echo Press a number (1 through 4) to select the option you want:
echo.
choice /c:1234
echo.
if errorlevel 4 goto realend
if errorlevel 3 goto mainmenu
if errorlevel 2 goto playsvga
if errorlevel 1 goto playdemo

:playsvga
cls
mw2demo -svga
goto realend

:playdemo
cls
mw2demo
goto realend

:realend
echo.
echo Thank you for trying Activision's MechWarrior 2 demo.
echo.
echo In the future, use any of the following commands from 
echo the MechWarrior 2 Demo directory:
echo.
echo     SETUP           Change input and sound devices.
echo     MW2DEMO         To run the demo in standard VGA mode.
echo     MW2DEMO -SVGA   To run the demo in SVGA mode.
echo.
echo We hope you have enjoyed the MechWarrior 2 demo, and
echo remember...................Death is your birthright!
echo.
@echo on
